//Description:
//Recursive trifold symmetry
//Glass finish
//Huge resolution looks best

//Author: Ben Scheele
//Date: 1-9-2003 and 3-18-03

camera {
  location -60*z-30*y
  up y
  right x
  angle 1.15
  look_at -.05*y
  }

light_source{ <50,100,-50>*.8 rgb 1 }

sky_sphere{
  pigment{ 
    gradient z triangle_wave 
    color_map{ [ 0 rgb <.4,.4,.5> ][ .5 rgb <.5,.5,.65> ][ 1 rgb <.6,.6,.8> ] }
    phase .5 frequency 1
  }
}

#macro Unit1(b,r) 
merge{
  cylinder { -x/2, x/2+b, r hollow }
  sphere { -x/2 r hollow }
}
#end
 
#declare Unit =
difference{
  Unit1(0,.15)
  object{ Unit1(.1*x,.1) } 

}  
               
#declare a = -.25;
#declare b = .5;               
               
#declare n = 1;
#declare endn = 9;  // level of recursion, # of objects x 3 for each step up 
#while (n < endn )
     
  #declare Unit = 
    union{
      object{ Unit scale 1/2 translate <a,b/sqrt(3),0> rotate 0*30*y }
      object{ Unit scale 1/2 translate <a,b/sqrt(3),0> rotate 120*z rotate -30*y }
      object{ Unit scale 1/2 translate <a,b/sqrt(3),0> rotate -120*z rotate 30*y }
    
    }  
    
  object{ Unit
  
   pigment{ rgbf <1-n/endn,0,n/endn,.5-.2*n/endn> transmit .7-.2*n/endn }
   
    finish{
      specular 0.7
      roughness 0.001
      brilliance .004
      phong .3
      diffuse .8
      reflection{
        0.1, 0.9   
        falloff .5
        metallic .15   
      }
      conserve_energy
    } 
    
    interior{
      ior 1.5  
      caustics 1.5
      fade_distance .5
      fade_power 2
    }
  }  

#declare n = n + 1;
#end